Mix.install([
  {:benchee, "~> 1.0"},
  {:plug, path: "."}
])

defmodule OldCookies do
  def decode(cookie) when is_binary(cookie) do
    Map.new(decode_kv(cookie, []))
  end

  defp decode_kv("", acc), do: acc
  defp decode_kv(<<h, t::binary>>, acc) when h in [?\s, ?\t], do: decode_kv(t, acc)
  defp decode_kv(kv, acc) when is_binary(kv), do: decode_key(kv, "", acc)

  defp decode_key(<<h, t::binary>>, _key, acc) when h in [?\s, ?\t, ?\r, ?\n, ?\v, ?\f],
    do: skip_until_cc(t, acc)

  defp decode_key(<<?;, t::binary>>, _key, acc), do: decode_kv(t, acc)
  defp decode_key(<<?=, t::binary>>, "", acc), do: skip_until_cc(t, acc)
  defp decode_key(<<?=, t::binary>>, key, acc), do: decode_value(t, "", 0, key, acc)
  defp decode_key(<<h, t::binary>>, key, acc), do: decode_key(t, <<key::binary, h>>, acc)
  defp decode_key(<<>>, _key, acc), do: acc

  defp decode_value(<<?;, t::binary>>, value, spaces, key, acc),
    do: decode_kv(t, [{key, trim_spaces(value, spaces)} | acc])

  defp decode_value(<<?\s, t::binary>>, value, spaces, key, acc),
    do: decode_value(t, <<value::binary, ?\s>>, spaces + 1, key, acc)

  defp decode_value(<<h, t::binary>>, _value, _spaces, _key, acc)
       when h in [?\t, ?\r, ?\n, ?\v, ?\f],
       do: skip_until_cc(t, acc)

  defp decode_value(<<h, t::binary>>, value, _spaces, key, acc),
    do: decode_value(t, <<value::binary, h>>, 0, key, acc)

  defp decode_value(<<>>, value, spaces, key, acc),
    do: [{key, trim_spaces(value, spaces)} | acc]

  defp skip_until_cc(<<?;, t::binary>>, acc), do: decode_kv(t, acc)
  defp skip_until_cc(<<_, t::binary>>, acc), do: skip_until_cc(t, acc)
  defp skip_until_cc(<<>>, acc), do: acc

  defp trim_spaces(value, 0), do: value
  defp trim_spaces(value, spaces), do: binary_part(value, 0, byte_size(value) - spaces)
end

defmodule NewCookies do
  def decode(cookie) when is_binary(cookie) do
    Map.new(decode_kv(cookie, []))
  end

  defp decode_kv("", acc), do: acc
  defp decode_kv(<<h, t::binary>>, acc) when h in [?\s, ?\t], do: decode_kv(t, acc)
  defp decode_kv(kv, acc) when is_binary(kv), do: decode_key(kv, kv, 0, acc)

  defp decode_key(<<h, t::binary>>, _key_rest, _len, acc) when h in [?\s, ?\t, ?\r, ?\n, ?\v, ?\f],
    do: skip_until_cc(t, acc)

  defp decode_key(<<?;, t::binary>>, _key_rest, _len, acc), do: decode_kv(t, acc)
  defp decode_key(<<?=, t::binary>>, _key_rest, 0, acc), do: skip_until_cc(t, acc)
  defp decode_key(<<?=, t::binary>>, key_rest, len, acc) do
    key = binary_part(key_rest, 0, len)
    decode_value(t, t, 0, 0, key, acc)
  end
  defp decode_key(<<_, t::binary>>, key_rest, len, acc), do: decode_key(t, key_rest, len + 1, acc)
  defp decode_key(<<>>, _key_rest, _len, acc), do: acc

  defp decode_value(<<?;, t::binary>>, val_rest, len, spaces, key, acc) do
    value = binary_part(val_rest, 0, len - spaces)
    decode_kv(t, [{key, value} | acc])
  end
  defp decode_value(<<?\s, t::binary>>, val_rest, len, spaces, key, acc) do
    decode_value(t, val_rest, len + 1, spaces + 1, key, acc)
  end
  defp decode_value(<<h, t::binary>>, _val_rest, _len, _spaces, _key, acc) when h in [?\t, ?\r, ?\n, ?\v, ?\f],
    do: skip_until_cc(t, acc)
  defp decode_value(<<_, t::binary>>, val_rest, len, _spaces, key, acc) do
    decode_value(t, val_rest, len + 1, 0, key, acc)
  end
  defp decode_value(<<>>, val_rest, len, spaces, key, acc) do
    value = binary_part(val_rest, 0, len - spaces)
    [{key, value} | acc]
  end

  defp skip_until_cc(<<?;, t::binary>>, acc), do: decode_kv(t, acc)
  defp skip_until_cc(<<_, t::binary>>, acc), do: skip_until_cc(t, acc)
  defp skip_until_cc(<<>>, acc), do: acc
end

Benchee.run(
  %{
    "Old Cookie Decoder" => fn input -> OldCookies.decode(input) end,
    "New Cookie Decoder (Optimized)" => fn input -> NewCookies.decode(input) end
  },
  inputs: %{
    "1. Single Cookie" => "session_id=abc123xyz",
    "2. Multi Cookies (Standard)" => "session_id=abc123xyz; user_id=42; theme=dark; logged_in=true",
    "3. Cookies with Whitespaces" => "  foo=bar  ;   baz=qux;other=val   ",
    "4. Malformed/Ignored Pairs" => "valid=one; invalid; valid2=two; =no_key; valid3=three",
    "5. Unicode Values" => "user=barna; location=Budapest; greeting=😊"
  },
  time: 2,
  memory_time: 2
)